DFPlayerMiniでMP3を鳴らしてみた

/*
 * ▼ベースは、下記の公式チュートリアル
 * https://wiki.dfrobot.com/DFPlayer_Mini_SKU_DFR0299
 * 
 * それに、タクトスイッチによる制御を追加。以下のアドレスのものを改造
 * https://www.electronics-lab.com/project/mp3-player-using-arduino-dfplayer-mini/
 * 
 * コマンド群(関数)の説明はこちらのサイトから
 * https://www.wwwmaplesyrup-cs6.work/entry/2019/02/10/152415
 */


/***************************************************
DFPlayer - A Mini MP3 Player For Arduino
 <https://www.dfrobot.com/index.php?route=product/product&product_id=1121>

 ***************************************************
 This example shows the basic function of library for DFPlayer.

 Created 2016-12-07
 By [Angelo qiao](Angelo.qiao@dfrobot.com)

 GNU Lesser General Public License.
 See <http://www.gnu.org/licenses/> for details.
 All above must be included in any redistribution
 ****************************************************/

/***********Notice and Trouble shooting***************
 1.Connection and Diagram can be found here
 <https://www.dfrobot.com/wiki/index.php/DFPlayer_Mini_SKU:DFR0299#Connection_Diagram>
 2.This code is tested on Arduino Uno, Leonardo, Mega boards.
 ****************************************************/

#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

SoftwareSerial mySoftwareSerial(10, 11); // RX, TX
DFRobotDFPlayerMini myDFPlayer;
void printDetail(uint8_t type, int value);

/* 追加分 */
# define ACTIVATED LOW   // ※pinModeを設定後、セットアップでHIGHにする。
int buttonNext = 4;
int buttonPause = 6;
int buttonPrevious = 5;
int buttonVup = 3;
int buttonVdown = 2;
boolean isPlaying = false;


void setup()
{
  mySoftwareSerial.begin(9600);
  Serial.begin(115200);

  Serial.println();
  Serial.println(F("DFRobot DFPlayer Mini Demo"));
  Serial.println(F("Initializing DFPlayer ... (May take 3~5 seconds)"));

  if (!myDFPlayer.begin(mySoftwareSerial)) {  //Use softwareSerial to communicate with mp3.
    Serial.println(F("Unable to begin:"));
    Serial.println(F("1.Please recheck the connection!"));
    Serial.println(F("2.Please insert the SD card!"));
    while(true);
  }
  Serial.println(F("DFPlayer Mini online."));

  myDFPlayer.volume(20);  //Set volume value. From 0 to 30
  
  myDFPlayer.enableLoopAll(); //loop all mp3 files.
 
/* 追加分 */
  pinMode(buttonPause, INPUT);
  digitalWrite(buttonPause,HIGH);
  pinMode(buttonNext, INPUT);
  digitalWrite(buttonNext,HIGH);
  pinMode(buttonPrevious, INPUT);
  digitalWrite(buttonPrevious,HIGH);
  pinMode(buttonVup, INPUT);
  digitalWrite(buttonVup,HIGH);
  pinMode(buttonVdown, INPUT);
  digitalWrite(buttonVdown,HIGH);

  isPlaying = true;
}

void loop()
{

// 一時停止
 if (digitalRead(buttonPause) == ACTIVATED)
  {
    if(isPlaying)
    {
      myDFPlayer.pause();
      isPlaying = false;
      delay(1000);    // ※処理が早すぎて、delayを入れないと指が離れる前に、次の判定が来てフラグを立ててもすぐ倒してしまう。
    }else
    {
      myDFPlayer.start();   //start the mp3 from the pause
      isPlaying = true;
      delay(1000);    // ※処理が早すぎて、delayを入れないと指が離れる前に、次の判定が来てフラグを立ててもすぐ倒してしまう。
    }
  }

// 次へ
 if (digitalRead(buttonNext) == ACTIVATED)
  {
    if(isPlaying)
    {
      myDFPlayer.next();
      delay(1000);  
    }
  }

// 前へ
   if (digitalRead(buttonPrevious) == ACTIVATED)
  {
    if(isPlaying)
    {
      myDFPlayer.previous();
      delay(1000);
    }
  }

// 音量増大
   if (digitalRead(buttonVup) == ACTIVATED)
  {
    if(isPlaying)
    {
      myDFPlayer.volumeUp();
      delay(1000);
    }
  }

// 音量増大
   if (digitalRead(buttonVdown) == ACTIVATED)
  {
    if(isPlaying)
    {
      myDFPlayer.volumeDown();
      delay(1000);
    }
  }

  if (myDFPlayer.available()) {
    printDetail(myDFPlayer.readType(), myDFPlayer.read()); //Print the detail message from DFPlayer to handle different errors and states.
  }
}

void printDetail(uint8_t type, int value){
  switch (type) {
    case TimeOut:
      Serial.println(F("Time Out!"));
      break;
    case WrongStack:
      Serial.println(F("Stack Wrong!"));
      break;
    case DFPlayerCardInserted:
      Serial.println(F("Card Inserted!"));
      break;
    case DFPlayerCardRemoved:
      Serial.println(F("Card Removed!"));
      break;
    case DFPlayerCardOnline:
      Serial.println(F("Card Online!"));
      break;
    case DFPlayerPlayFinished:
      Serial.print(F("Number:"));
      Serial.print(value);
      Serial.println(F(" Play Finished!"));

      // ※次へボタンを押すと、演奏終了後に停止してループが終了してしまうので。
      myDFPlayer.next();
      delay(1000);  
      
      break;
    case DFPlayerError:
      Serial.print(F("DFPlayerError:"));
      switch (value) {
        case Busy:
          Serial.println(F("Card not found"));
          break;
        case Sleeping:
          Serial.println(F("Sleeping"));
          break;
        case SerialWrongStack:
          Serial.println(F("Get Wrong Stack"));
          break;
        case CheckSumNotMatch:
          Serial.println(F("Check Sum Not Match"));
          break;
        case FileIndexOut:
          Serial.println(F("File Index Out of Bound"));
          break;
        case FileMismatch:
          Serial.println(F("Cannot Find File"));
          break;
        case Advertise:
          Serial.println(F("In Advertise"));
          break;
        default:
          break;
      }
      break;
    default:
      break;
  }
}